DROP PROCEDURE IF EXISTS uspGetTanarDolgozatTantargyak
GO

CREATE PROCEDURE uspGetTanarDolgozatTantargyak
   @pTanarId int
  ,@pTanevId int
  ,@OktNevKatTipus int
  ,@pSzuperOsztalyfonok int
  ,@pDatum date
AS BEGIN
  SET NOCOUNT ON
  SELECT DISTINCT
     t.ID AS TantargyId
    ,t.C_NEV AS TantargyNev
  FROM T_OSZTALYCSOPORT_OSSZES ocs
      INNER JOIN T_FOGLALKOZAS_OSSZES f ON ocs.ID = f.C_OSZTALYCSOPORTID
        AND f.TOROLT = 'F'
      INNER JOIN T_TANTARGY_OSSZES t ON t.ID = f.C_TANTARGYID
  WHERE ocs.TOROLT = 'F'
    AND ocs.C_TANEVID = @pTanevId
    AND EXISTS( SELECT 1 
                FROM T_TANULOCSOPORT_OSSZES tcs 
                WHERE tcs.C_OSZTALYCSOPORTID=ocs.ID 
                  AND tcs.TOROLT='F'
                  AND @pDatum >= tcs.C_BELEPESDATUM
                  AND (tcs.C_KILEPESDATUM IS NULL OR tcs.C_KILEPESDATUM > @pDatum)
                  AND tcs.C_TANULOID IN (SELECT ID FROM fnGetOsztalyfonokOsztalyanakTanuloi(@pTanarId, @pSzuperOsztalyfonok, ocs.C_FELADATKATEGORIAID, @pDatum)))
  UNION
  SELECT
     t.ID AS TantargyId
    ,t.C_NEV AS TantargyNev
  FROM T_FOGLALKOZAS_OSSZES f
    INNER JOIN T_OSZTALYCSOPORT_OSSZES ocs ON ocs.ID = f.C_OSZTALYCSOPORTID
    INNER JOIN T_TANTARGY_OSSZES t ON t.ID = f.C_TANTARGYID
      AND t.TOROLT = 'F'
  WHERE (f.C_TANARID = @pTanarId OR @pSzuperOsztalyfonok = 1)
    AND ocs.C_TANEVID = @pTanevId
  ORDER BY TantargyNev
END
GO