-- =============================================
-- Description:  <Előszedjük a szamonkeres elorejelzeseket a megadott paraméterek alapján>
-- =============================================
DROP PROCEDURE IF EXISTS uspGetSzamonkeresElorejelzesekByDateRange
GO

CREATE PROCEDURE [dbo].[uspGetSzamonkeresElorejelzesekByDateRange] 
   @pIntezmenyId int
  ,@pTanevId int
  ,@pDatumTol datetime = NULL
  ,@pDatumIg datetime = NULL
AS BEGIN
  SET NOCOUNT ON;

  SELECT DISTINCT
     sze.ID AS ID
    ,oo.C_ORASZAM AS Oraszam
    ,targy.C_NEV AS Tantargy
    ,ISNULL(helyettestanar.C_NYOMTATASINEV, tanar.C_NYOMTATASINEV) AS Tanar
    ,dib.C_NAME AS SzamonkeresMod
    ,sze.C_SZAMONKERESMODID AS SzamonkeresModId
    ,rogzito.C_NYOMTATASINEV AS RogzitoTanar
    ,sze.C_ROGZITOID AS RogzitoId
    ,ocs.C_NEV AS Osztaly
    ,sze.C_ROGZITESDATUMA AS RogzitesDatum
    ,sze.C_SZAMONKERESDATUMA AS SzamonkeresDatum
    ,sze.C_ORARENDIORAGROUPID AS GroupId
    ,sze.C_SZAMONKERESMEGNEVEZES AS SzamonkeresMegnevezes
  FROM T_SZAMONKERESELOREJELZES sze
    INNER JOIN T_ORARENDIORA oo ON oo.C_ORARENDIORAGROUPID = sze.C_ORARENDIORAGROUPID
      AND (sze.C_SZAMONKERESDATUMA >= oo.C_ORAERVENYESSEGKEZDETE 
      AND (sze.C_SZAMONKERESDATUMA < oo.C_ORAERVENYESSEGVEGE OR (sze.C_SZAMONKERESDATUMA = oo.C_ORAERVENYESSEGVEGE AND sze.C_SZAMONKERESDATUMA = oo.C_ORAERVENYESSEGKEZDETE)))
      AND oo.TOROLT = 'F'
      AND (oo.C_EGYEDINAP = 'F' OR  oo.C_ORAERVENYESSEGVEGE = oo.C_ORAERVENYESSEGKEZDETE)
    INNER JOIN T_TANTARGY targy ON targy.ID = oo.C_TANTARGYID 
      AND targy.TOROLT = 'F'
    INNER JOIN T_FELHASZNALO tanar ON tanar.ID = oo.C_TANARID 
      AND tanar.TOROLT = 'F'
    INNER JOIN T_FELHASZNALO rogzito ON rogzito.ID = sze.C_ROGZITOID 
      AND rogzito.TOROLT = 'F'
    INNER JOIN T_OSZTALYCSOPORT ocs ON ocs.ID = oo.C_OSZTALYCSOPORTID 
      AND ocs.TOROLT = 'F'
    INNER JOIN T_DICTIONARYITEMBASE dib ON dib.ID = sze.C_SZAMONKERESMODID 
      AND dib.C_INTEZMENYID = sze.C_INTEZMENYID 
      AND dib.C_TANEVID = sze.C_TANEVID 
    LEFT JOIN T_HELYETTESITESIIDOSZAK helyettes ON helyettes.C_HELYETTESITETTORARENDID = oo.ID 
    AND helyettes.C_HELYETTESITESNAPJA = sze.C_SZAMONKERESDATUMA
      AND helyettes.TOROLT = 'F'
    LEFT JOIN T_FELHASZNALO helyettestanar ON helyettestanar.ID = helyettes.C_HELYETTESTANAROKID 
      AND helyettestanar.TOROLT = 'F'
  WHERE sze.C_SZAMONKERESDATUMA BETWEEN @pDatumtol AND @pDatumig 
    AND sze.C_INTEZMENYID = @pIntezmenyId 
    AND sze.C_TANEVID = @pTanevId

END
GO