init

Kreta.DataAccess.Migrations/Scripts/Archive/20180621180348_KRETA_6022/sp_FollowUpTanuloEmail.sql

@@ -0,0 +1,79 @@
+-- =============================================
+-- Author: Szekeres András
+-- Create date:  2018.04.24.
+-- Description:  Egy tanuló email címeinek frissítése a következõ tanévre
+-- =============================================
+
+IF OBJECT_ID('sp_FollowUpTanuloEmail') IS NOT NULL BEGIN
+  DROP PROCEDURE sp_FollowUpTanuloEmail
+END;
+GO
+
+CREATE PROCEDURE sp_FollowUpTanuloEmail
+  @intezmenyId int,
+  @aktTanevId int,
+  @kovTanevId int,
+  @tanuloId int
+AS
+BEGIN
+  DECLARE @kovTanuloId int;
+  
+  SELECT @kovTanuloId = kov.ID
+  FROM T_FELHASZNALO_OSSZES akt
+    INNER JOIN T_FELHASZNALO_OSSZES kov ON akt.C_OKTATASIAZONOSITO = kov.C_OKTATASIAZONOSITO AND kov.C_TANEVID = @kovTanevId AND kov.C_INTEZMENYID = @intezmenyId
+  WHERE akt.ID = @tanuloId
+    AND akt.C_INTEZMENYID = @intezmenyId
+    AND akt.C_TANEVID = @aktTanevId
+    AND kov.TOROLT = 'F'
+    AND akt.TOROLT = 'F'
+
+  IF @kovTanuloId IS NOT NULL BEGIN
+    DELETE FROM T_EMAIL_OSSZES
+    WHERE C_FELHASZNALOID = @kovTanuloId
+      AND C_GONDVISELOID IS NULL
+      AND C_INTEZMENYID = @intezmenyId
+      AND C_TANEVID = @kovTanevId;
+
+    INSERT INTO T_EMAIL_OSSZES (
+       C_EMAILTIPUSA
+      ,C_EMAILCIM
+      ,C_ALAPERTELMEZETT
+      ,C_ISPUBLIC
+      ,C_GONDVISELOID
+      ,C_FELHASZNALOID
+      ,C_INTEZMENYID
+      ,C_TANEVID
+      ,TOROLT
+      ,SERIAL
+      ,LASTCHANGED
+      ,CREATED
+      ,MODIFIER
+      ,CREATOR
+      ,ELOZOTANEVIREKORDID
+      ,NNID
+    ) SELECT
+       C_EMAILTIPUSA
+      ,C_EMAILCIM
+      ,C_ALAPERTELMEZETT
+      ,C_ISPUBLIC
+      ,C_GONDVISELOID
+      ,@kovTanuloId
+      ,C_INTEZMENYID
+      ,@kovTanevId
+      ,TOROLT
+      ,0
+      ,GETDATE()
+      ,GETDATE()
+      ,MODIFIER
+      ,MODIFIER
+      ,ID
+      ,NULL
+    FROM T_EMAIL_OSSZES
+    WHERE C_FELHASZNALOID = @tanuloId
+      AND C_GONDVISELOID IS NULL
+      AND C_INTEZMENYID = @intezmenyId
+      AND C_TANEVID = @aktTanevId
+      AND TOROLT = 'F';
+  END
+END
+GO